1с статьи | Курс-репетитор программиста 1С

Создание и обход

ДеревоЗначений = Новый ДеревоЗначений;	

// Полностью скопируем дерево значений
КопияДереваЗначений = ДеревоЗначений.Скопировать();

// РАБОТА С КОЛОНКАМИ ДЕРЕВА
КолонкиДерева = ДеревоЗначений.Колонки; // Доступ к КоллекцииКолонокДереваЗначений 

// Добавим колонку Добавить(<Имя>, <Тип>, <Заголовок>, <Ширина>) 
КолонкаДерева = КолонкиДерева.Добавить("ИмяКолонки1",
Новый ОписаниеТипов("Число"), "ЗаголовокКолонки1");

// После создания колонки невозможно изменить её Тип 
// Но возможно поменять Имя, Заголовок и Ширину
КолонкаДерева.Имя = "Колонка1";
КолонкаДерева.Заголовок = "Колонка1";
КолонкаДерева.Ширина = 20; // Ширина задаётся числом символов 

// Вставим новую колонку на 0 позицию 
// Вставить(<Индекс>, <Имя>, <Тип>, <Заголовок>, <Ширина>)
ВставленнаяКолонка = КолонкиДерева.Вставить(0, "Колонка0",
Новый ОписаниеТипов("Число"), "Колонка0", 20); 

//РАБОТА СО СТРОКАМИ ДЕРЕВА
СтрокиДерева = ДеревоЗначений.Строки;
// Добавим строку	
СтрокаДерева = СтрокиДерева.Добавить(); 
// В свойствах строки есть доступные колонки
СтрокаДерева.Колонка0 = 17; 
СтрокаДерева.Колонка1 = 18;

// Вставим строку на 0 позицию
// Вставить(<Индекс>)
ВставленнаяСтрока = СтрокиДерева.Вставить(0);
ВставленнаяСтрока.Колонка0 = 40; 
ВставленнаяСтрока.Колонка1 = 50;

// Добавим подстроку строки дерева
ПодстрокаДерева = СтрокаДерева.Строки.Добавить();
// Колонки те же
ПодстрокаДерева.Колонка0 = 43;
ПодстрокаДерева.Колонка1 = 89;

// Удалим строку
// Передаем строку дерева
СтрокиДерева.Удалить(СтрокаДерева);
// Передаём индекс строки в дереве
СтрокиДерева.Удалить(0);
// Если у строки имеются подчиненные строки, они также будут удалены

// Удалим все строки текущего уровня
// Если у строк данного уровня были подчиненные строки, то они также будут удалены
// Структура колонок остается неизменной
СтрокиДерева.Очистить();

// Удалим все созданные колонки дерева
// При этом также удаляются все его строки
КолонкиДерева.Очистить();

// Обход строк осуществляется рекурсивно. Знаете как?

Показать решение

 
    
&НаСервере
Процедура ОбходДереваЗначений(ДеревоЗначений) 
	
	// Получаем подстроки дерева
	Для Каждого Строка Из ДеревоЗначений.Строки Цикл
		ОбходДереваЗначенийРекурсивно(Строка.Строки);
	КонецЦикла
	
КонецПроцедуры 

&НаСервере
Процедура ОбходДереваЗначенийРекурсивно(Строки) 
			
	Для Каждого Строка Из Строки Цикл
		// Обходим подстроки строки рекурсивно
		ОбходДереваЗначенийРекурсивно(Строка.Строки);
	КонецЦикла
	
КонецПроцедуры

Методы колонок дерева значений

ДеревоЗначений = Новый ДеревоЗначений;
КолонкиДерева = ДеревоЗначений.Колонки;

КолонкаДерева0 = КолонкиДерева.Добавить("Колонка0", Новый ОписаниеТипов("Число"), "Колонка0");
КолонкаДерева1 = КолонкиДерева.Добавить("Колонка1", Новый ОписаниеТипов("Число"), "Колонка1");

// Найдем индекс колонки
// Индекс(<Колонка>)	
ИндексКолонки = КолонкиДерева.Индекс(КолонкаДерева1); // Вернёт 1 
// Если не найдено, то возвращается -1.

// Получим колонку по индексу
// Получить(<Индекс>)
КолонкаПоИндексу = КолонкиДерева.Получить(ИндексКолонки); // Вернёт Колонка1

// Колонку можно сдвинуть
// Сдвинуть(<Колонка>, <Смещение>)
// Отрицательное смещение обозначает сдвиг в начало коллекции
КолонкиДерева.Сдвинуть(КолонкаДерева1, -1); // Сдвинет Колонка1 с 1 позиции в 0
// Положительное смещение обозначает сдвиг в конец коллекции
КолонкиДерева.Сдвинуть(КолонкаДерева1, 1); // Сдвинет Колонка1 с 0 позиции в 1
	
// Получить количество колонок
КоличествоКолонок = КолонкиДерева.Количество();// 2

// Поиск колонки
// Найти(<НаименованиеКолонки>)
НайденнаяКолонка = КолонкиДерева.Найти("Колонка0"); // Вернёт Колонку0 с типом КолонкаДереваЗначений
// Если указанная колонка отсутствует, то возвращается значение Неопределено

Методы строк дерева значений

ДеревоЗначений = Новый ДеревоЗначений;

КолонкиДерева = ДеревоЗначений.Колонки;
СтрокиДерева = ДеревоЗначений.Строки; 

КолонкаДерева0 = КолонкиДерева.Добавить("Колонка0", Новый ОписаниеТипов("Число"), "Колонка0");
КолонкаДерева1 = КолонкиДерева.Добавить("Колонка1", Новый ОписаниеТипов("Число"), "Колонка1");

СтрокаДерева0 = СтрокиДерева.Добавить(); 
СтрокаДерева0.Колонка0 = 17;
СтрокаДерева0.Колонка1 = 54;

СтрокаДерева1 = СтрокиДерева.Добавить(); 
СтрокаДерева1.Колонка0 = 71;
СтрокаДерева1.Колонка1 = 45;  
	
// Получим индекс строки
ИндексСтроки = СтрокиДерева.Индекс(СтрокаДерева1); // 1
// Если не найдено, то возвращается -1

// Получим строку по индексу
// Получить(<Индекс>)
СтрокаДерева = СтрокиДерева.Получить(ИндексСтроки); // Вернет СтрокуДерева1

// Передвинем строку дерева
// Сдвинуть(<Строка>, <Смещение>)
// Отрицательное смещение обозначает уменьшение текущего индекса (сдвиг к началу коллекции)
СтрокиДерева.Сдвинуть(СтрокаДерева1, -1); // Сдвинет с 1 Позиции на 0
// Положительное смещение обозначает увеличение текущего индекса (сдвиг к концу коллекции)
СтрокиДерева.Сдвинуть(СтрокаДерева1, 1); // Сдвинет с 0 Позиции на 1 

// Получим итоги по колонке 
// Итог(<Колонка>, <ВключатьПодчиненные>)
ИтогПоКолонке1 = СтрокиДерева.Итог(1, Ложь); // Вернет 99
// Колонку можно указать по имени, индексу или передать колонку дерева

// Количество строк
КоличествоСтрок = СтрокиДерева.Количество(); // 2

// Найдём строку дерева по значению
// Найти(<Значение>, <Колонки>, <ВключатьПодчиненные>)
ИскомаяСтрока = СтрокиДерева.Найти(71, "Колонка0, Колонка1", Ложь);
// Вернёт первую строку со значением 71 в одной из переданных колонок
// Если значение не найдено, то возвращается значение Неопределено

// Найдём все строки дерева с нужным значением по колонкам
// НайтиСтроки(<ПараметрыОтбора>, <ВключатьПодчиненные>)
МассивИскомыхСтрок = СтрокиДерева.НайтиСтроки(
	Новый Структура("Колонка0, Колонка1", 17, 54), Ложь);
// Массив хранит ссылки на строки дерева значений, 
// то есть при изменении строки в дереве, значение в массиве тоже будет изменено
	
// Отсортируем строки
// Сортировать(<СтрокаСортировки>, <ВключатьПодчиненные>, <ОбъектСравнения>)
СтрокиДерева.Сортировать("Колонка0 Возр, Колонка1 Убыв", Ложь, Новый СравнениеЗначений);
// Сперва отсортируются строки по Возростанию в колонке0
// Затем отсортируются по убыванию колонки1
// ПРИ ЭТОМ
// Если третим параметром указан объект сравнения то:
// 		Элементы, чьи типы не совпадают, сравниваются по коду типа;
// 		Элементы простых типов сравниваются по значению;
// 		Объекты сравниваются по идентификатору;
 // 		Моменты времени сравниваются по дате и идентификатору объекта;
// 		Элементы остальных типов сравниваются по строковому представлению.
// Если не указывать третий параметр то:
// 		Элементы, чьи типы не совпадают, сравниваются по коду типа;
// 		Элементы простых типов сравниваются по значению;
// 		Элементы остальных типов сравниваются по строковому представлению. 

// Выгрузим колонку 
// В параметрах передадим колонку тип КолонкаДереваЗначений
МассивЗначенийКолонки1 = СтрокиДерева.ВыгрузитьКолонку(КолонкаДерева1);
// В параметрах передадим имя колонки тип Строка
МассивЗначенийКолонки1 = СтрокиДерева.ВыгрузитьКолонку("Колонка1");
// В параметрах передадим Индекс колонки тип Число
МассивЗначенийКолонки1 = СтрокиДерева.ВыгрузитьКолонку(1);
// Возвращается массив значений строк текущего уровня переданной колонки
// В нашем примере: 54 45

// Загрузим значения в колонку0
// В параметрах передадим колонку
СтрокиДерева.ЗагрузитьКолонку(МассивЗначенийКолонки1, КолонкаДерева1); 
// В параметрах передадим имя колонки
СтрокиДерева.ЗагрузитьКолонку(МассивЗначенийКолонки1, "Колонка0");
// В параметрах передадим индекс 
СтрокиДерева.ЗагрузитьКолонку(МассивЗначенийКолонки1, 0);
// Значения из массива скопируются в строки колонки

Сообщить(СтрокаДерева0.Колонка0);
Сообщить(СтрокаДерева1.Колонка0);

// Что будет выведено?

Показать решение

ДеревоЗначений (ValueTree)

Описание: Используется для доступа к свойствам и методам дерева значений в целом. Объект, представляющий собой древовидную структуру, обладает сходной функциональностью с таблицей значений, а также обладает возможностью добавлять подчиненные строки к какой-либо строке дерева. Внимание! В толстом клиенте (обычное приложение) передача значений данного типа с клиента на сервер и обратно приводит к возникновению исключения.

Свойства:

Колонки (Columns)

Описание: Тип: КоллекцияКолонокДереваЗначений.

Содержит коллекцию колонок дерева значений.

Строки (Rows). Тип: КоллекцияСтрокДереваЗначений.

Содержит коллекцию строк 1-го уровня дерева значений.

Конструкторы (По умолчанию) Синтаксис: Новый ДеревоЗначений

КоллекцияКолонокДереваЗначений.Вставить (Insert)

Синтаксис: Вставить(<Индекс>, <Имя>, <Тип>, <Заголовок>, <Ширина>)

Параметры:

<Индекс> (обязательный) Тип: Число.

Индекс в коллекции колонок, с которым необходимо вставить колонку.

<Имя> (необязательный) Тип: Строка.

Имя колонки.

Значение по умолчанию: Пустая строка.

<Тип> (необязательный) Тип: ОписаниеТипов.

Объект, описывающий допустимые типы значений для колонки. Если параметр не указан, в колонке можно будет хранить значение любого типа.

<Заголовок> (необязательный) Тип: Строка.

Заголовок колонки. Используется при визуальном отображении дерева значений.

Значение по умолчанию: Пустая строка.

<Ширина> (необязательный) Тип: Число.

Ширина колонки в символах. Используется при визуальном отображении дерева значений.

Значение по умолчанию: 0.

Возвращаемое значение: Тип: КолонкаДереваЗначений. Вставленная колонка.

Описание: Вставляет колонку в заданную позицию коллекции колонок дерева значений.

Доступность: Сервер, толстый клиент, внешнее соединение, мобильное приложение (сервер), мобильный автономный сервер.

КоллекцияКолонокДереваЗначений.Добавить (Add)

Синтаксис: Добавить(<Имя>, <Тип>, <Заголовок>, <Ширина>)

Параметры:

<Имя> (необязательный) Тип: Строка.

Имя колонки.

Значение по умолчанию: Пустая строка.

<Тип> (необязательный) Тип: ОписаниеТипов.

<Заголовок> (необязательный) Тип: Строка.

Заголовок колонки. Используется при визуальном отображении дерева значений.

Значение по умолчанию: Пустая строка.

<Ширина> (необязательный) Тип: Число.

Ширина колонки в символах. Используется при визуальном отображении дерева значений.

Значение по умолчанию: 0.

Возвращаемое значение: Тип: КолонкаДереваЗначений.

Описание: Добавляет колонку в конец коллекции колонок дерева значений.

КоллекцияКолонокДереваЗначений.Индекс (IndexOf)

Синтаксис: Индекс(<Колонка>)

Параметры:

<Колонка> (обязательный) Тип: КолонкаДереваЗначений.

Колонка, для которой необходимо получить индекс.

Возвращаемое значение: Тип: Число. Индекс указанной колонки в коллекции. Если не найдено, то возвращается -1.

Описание: Получает индекс указанной колонки в коллекции колонок.

КоллекцияКолонокДереваЗначений.Количество (Count)

Синтаксис: Количество()

Возвращаемое значение: Тип: Число.

Описание: Получает количество колонок дерева значений.

КоллекцияКолонокДереваЗначений.Найти (Find)

Синтаксис: Найти(<НаименованиеКолонки>)

Параметры:

<НаименованиеКолонки> (обязательный) Тип: Строка. Наименование колонки дерева значений.

Возвращаемое значение: Тип: КолонкаДереваЗначений, Неопределено. Если указанная колонка отсутствует, то возвращается значение Неопределено.

Описание: Осуществляет поиск колонки дерева значений по имени.

КоллекцияКолонокДереваЗначений.Очистить (Clear)

Синтаксис: Очистить()

Описание: Удаляет все колонки дерева значений. При этом также удаляются все его строки.

КоллекцияКолонокДереваЗначений.Получить (Get)

Синтаксис: Получить(<Индекс>)

Параметры:

<Индекс> (обязательный) Тип: Число. Индекс колонки.

Возвращаемое значение: Тип: КолонкаДереваЗначений.

Описание: Получает значение по индексу. Работает аналогично оператору [].

Примечание: Применяется в случаях, когда использование оператора [] невозможно.

КоллекцияКолонокДереваЗначений.Сдвинуть (Move)

Синтаксис: Сдвинуть(<Колонка>, <Смещение>)

Параметры:

<Колонка> (обязательный) Тип: Число, КолонкаДереваЗначений. Индекс сдвигаемой колонки в коллекции или сама колонка.

<Смещение> (обязательный) Тип: Число. Количество колонок, на которое необходимо сдвинуть колонку. Положительное смещение обозначает сдвиг в конец, отрицательное - в начало коллекции.

Описание: Сдвигает колонку с заданным индексом на указанное смещение.

КоллекцияКолонокДереваЗначений.Удалить (Delete)

Синтаксис: Удалить(<Индекс>)

Параметры:

<Индекс> (обязательный) Тип: Число, КолонкаДереваЗначений. Индекс удаляемой колонки в коллекции или колонка.

Описание: Удаляет колонку в заданной позиции коллекции колонок дерева значений.

КоллекцияСтрокДереваЗначений.Вставить (Insert)

Синтаксис: Вставить(<Индекс>)

Параметры:

<Индекс> (обязательный) Тип: Число. Индекс позиции в коллекции строк данного уровня, в которую необходимо вставить строку.

Возвращаемое значение: Тип: СтрокаДереваЗначений. Вставленная строка.

Описание: Вставляет строку с указанным индексом в коллекцию строк данного уровня дерева значений.

КоллекцияСтрокДереваЗначений.ВыгрузитьКолонку (UnloadColumn)

Синтаксис: ВыгрузитьКолонку(<Колонка>)

Параметры:

<Колонка> (обязательный) Тип: Число, Строка, КолонкаДереваЗначений. Колонка, из которой нужно выгрузить значения. В качестве значения параметра может быть передан индекс колонки, имя колонки, либо колонка дерева значений.

Возвращаемое значение: Тип: Массив.

Описание: Создает массив и копирует в него значения, содержащиеся в колонке коллекции строк дерева значений.

Примечание: Значения из колонки выгружаются в порядке индексов строк в коллекции.

КоллекцияСтрокДереваЗначений.Добавить (Add)

Синтаксис: Добавить()

Возвращаемое значение: Тип: СтрокаДереваЗначений.

Описание: Добавляет строку в конец коллекции строк данного уровня дерева значений.

КоллекцияСтрокДереваЗначений.ЗагрузитьКолонку (LoadColumn)

Синтаксис: ЗагрузитьКолонку(<Массив>, <Колонка>)

Параметры:

<Массив> (обязательный) Тип: Массив. Массив значений для загрузки в колонку.

<Колонка> (обязательный) Тип: Число, Строка, КолонкаДереваЗначений. Колонка коллекции, в которую будут загружены значения из массива. В качестве значения параметра может быть передан индекс колонки, имя колонки, либо колонка дерева значений.

Описание: Загружает значения из массива в заданную колонку коллекции строк дерева значений.

Примечание: Значения из массива загружаются в колонку в порядке индексов.

КоллекцияСтрокДереваЗначений.Индекс (IndexOf)

Синтаксис: Индекс(<Строка>)

Параметры:

<Строка> (обязательный) Тип: СтрокаДереваЗначений. Строка, для которой необходимо получить индекс.

Возвращаемое значение: Тип: Число. Индекс указанной строки в коллекции. Если не найдено, то возвращается -1.

Описание: Получает индекс строки в коллекции строк дерева значений.

КоллекцияСтрокДереваЗначений.Итог (Total)

Синтаксис: Итог(<Колонка>, <ВключатьПодчиненные>)

Параметры:

<Колонка> (обязательный) Тип: Число, Строка, КолонкаДереваЗначений. Колонка, по которой подсчитывается итог. В качестве значения параметра может быть передан индекс колонки, имя колонки, либо колонка дерева значений.

<ВключатьПодчиненные> (необязательный) Тип: Булево. Определяет, будут ли включены в сумму итоги по подчиненным строкам (если таковые имеются). Истина - итоги будут включены. Значение по умолчанию: Ложь.

Возвращаемое значение: Тип: Число, Неопределено.

Описание: Суммирует значения всех строк в указанной колонке.Если в колонке установлен тип и он единственный, то при суммировании будет предприниматься попытка преобразования значения к типу Число.

Если колонке не присвоены типы, то в процессе суммирования будут принимать участие только значения, имеющие тип Число, значения других типов будут игнорироваться.

Если в колонке несколько типов и среди них есть тип Число, то в процессе суммирования будут принимать участие только значения, имеющие тип Число, значения других типов будут игнорироваться

Если в колонке несколько типов и среди них нет типа Число, то результатом будет значение Неопределено.

КоллекцияСтрокДереваЗначений.Количество (Count)

Синтаксис: Количество()

Возвращаемое значение: Тип: Число.

Описание: Получает количество строк данного уровня дерева значений.

КоллекцияСтрокДереваЗначений.Найти (Find)

Синтаксис: Найти(<Значение>, <Колонки>, <ВключатьПодчиненные>)

Параметры:

<Значение> (обязательный) Тип: Произвольный. Искомое значение.

<Колонки> (необязательный) Тип: Строка. Список имен колонок, в которых будет осуществляться поиск, разделенных запятыми.Если параметр не указан, поиск осуществляется по всем колонкам дерева. Значение по умолчанию: Пустая строка.

<ВключатьПодчиненные> (необязательный) Тип: Булево. Определяет, будут ли участвовать в поиске строки подчиненных коллекций (если таковые имеются). Истина - строки подчиненных коллекций участвуют в поиске. Значение по умолчанию: Ложь.

Возвращаемое значение: Тип: СтрокаДереваЗначений, Неопределено. Строка, которая содержит искомое значение. Если значение не найдено, то возвращается значение Неопределено.

Описание: Осуществляет поиск значения в дереве в указанных колонках коллекции строк дерева значений.

Примечание: Метод эффективно использовать для поиска уникальных значений.

КоллекцияСтрокДереваЗначений.НайтиСтроки (FindRows)

Синтаксис: НайтиСтроки(<ПараметрыОтбора>, <ВключатьПодчиненные>)

Параметры:

<ПараметрыОтбора> (обязательный) Тип: Структура. Задает условия поиска: ключ структуры определяет имя колонки, по которой будет осуществляться поиск, а значение структуры - искомое значение.

<ВключатьПодчиненные> (необязательный) Тип: Булево. Определяет, будут ли производиться поиск также в подчиненных коллекциях (если таковые имеются). Истина - поиск будет произведен. Значение по умолчанию: Ложь.

Возвращаемое значение: Тип: Массив. Массив из строк дерева значений, соответствующих заданному условию поиска. Замечание! Массив хранит ссылки на строки дерева значений, то есть при изменении строки в дереве, значение в массиве тоже будет изменено.

Описание: Осуществляет поиск строк из коллекции строк дерева значений, соответствующих заданному условию поиска.

Примечание: Метод эффективно использовать для выборки неуникальных значений.

КоллекцияСтрокДереваЗначений.Очистить (Clear)

Синтаксис: Очистить()

Описание: Удаляет все коллекции строки данного уровня дерева значений. Если у строк данного уровня были подчиненные строки, то они также будут удалены. Структура колонок остается неизменной.

КоллекцияСтрокДереваЗначений.Получить (Get)

Синтаксис: Получить(<Индекс>)

Параметры:

<Индекс> (обязательный) Тип: Число. Индекс строки.

Возвращаемое значение: Тип: СтрокаДереваЗначений.

Описание: Получает значение по индексу. Работает аналогично оператору [].

Примечание: Применяется в случаях, когда использование оператора [] невозможно.

КоллекцияСтрокДереваЗначений.Сдвинуть (Move)

Синтаксис: Сдвинуть(<Строка>, <Смещение>)

Параметры:

<Строка> (обязательный) Тип: Число. Индекс строки, которую надо сдвинуть.

<Смещение> (обязательный) Тип: Число. Количество строк, на которые необходимо сдвинуть строку. Положительное смещение обозначает увеличение текущего индекса (сдвиг к концу коллекции), отрицательное - уменьшение текущего индекса (сдвиг к началу коллекции).

Описание: Сдвигает строку на указанное количество позиций в коллекции строк данного уровня дерева значений.

КоллекцияСтрокДереваЗначений.Сортировать (Sort)

Синтаксис: Сортировать(<СтрокаСортировки>, <ВключатьПодчиненные>, <ОбъектСравнения>)

Параметры:

<СтрокаСортировки> (обязательный) Тип: Строка. Список имен колонок, разделенных запятыми, по которым производится сортировка таблицы. После каждого имени колонки через пробел может быть указано направление упорядочивания. Направление определяется: "Убыв" ("Desc") - упорядочивать по убыванию; "Возр" ("Asc") - упорядочивать по возрастанию. По умолчанию сортировка таблица производится по возрастанию. Порядок указания имен колонок таблицы определяет порядок сортировки. Это означает, что сначала таблица сортируется по колонке, указанной первой. Затем группы строк с одинаковым значением в этой колонке сортируются по колонке, которая указана второй, и так далее.

<ВключатьПодчиненные> (необязательный) Тип: Булево. Определяет, будут ли отсортированы коллекции подчиненных строк (если таковые имеются). Истина - коллекции будут отсортированы. Значение по умолчанию: Ложь.

<ОбъектСравнения> (необязательный) Тип: СравнениеЗначений. Объект для сравнения элементов. Если объект сравнения не задан, сравнение выполняется по следующим правилам:

элементы, чьи типы не совпадают, сравниваются по коду типа;

элементы простых типов сравниваются по значению

элементы остальных типов сравниваются по строковому представлению.

Описание: Сортирует строки коллекции в соответствии с указанными правилами сортировки.

КоллекцияСтрокДереваЗначений.Удалить (Delete)

Вариант синтаксиса: По объекту

Синтаксис: Удалить(<Строка>)

Параметры:

<Строка> (обязательный) Тип: СтрокаДереваЗначений. Строка, которую необходимо удалить из данной коллекции строк ДеревоЗначений.

Вариант синтаксиса: По индексу

Синтаксис: Удалить(<Индекс>)

Параметры:

<Индекс> (обязательный) Тип: Число. Индекс удаляемой строки.

Описание: Удаляет строку из коллекции строк данного уровня дерева значений. Если у строки имеются подчиненные строки, они также будут удалены.

ВыбратьСтроку (ChooseRow)

Синтаксис: ВыбратьСтроку(<Заголовок>, <НачальнаяСтрока>)

Параметры:

<Заголовок> (необязательный) Тип: Строка.

Заголовок диалога выбора строки.

Если заголовок не указан, то будет использован стандартный заголовок "Выберите строку".

<НачальнаяСтрока> (необязательный) Тип: СтрокаДереваЗначений.

Начальная строка дерева (будет выделенной при открытии диалога). Если не указана, то выделенной будет первая строка дерева.

Возвращаемое значение: Тип: СтрокаДереваЗначений, Неопределено.

Если пользователь отказался от выбора, возвращает Неопределено.

Описание: Вызывает модальное окно для выбора строки из дерева значений.

Доступность: Толстый клиент.

Скопировать (Copy)

Синтаксис: Скопировать()

Возвращаемое значение: Тип: ДеревоЗначений.

Описание: Создает полную копию исходного дерева значений.